DECLARE FUNCTION Dump$ ()
DECLARE SUB CATSend (Text$, SStep!, Speed!, c1!, c2!, c3!, c4!, c5!)
DECLARE FUNCTION DumpStr$ (b$)

rem ***************************************************************************
rem *   QT_Test.bas                                                           *
rem *                                                                         *
rem *   Simulates the functionality of the QuickTune for the YAESU FT-817     *
rem *   (can be found at http://www.min.at/OE1RIB/QT)                         *
rem *                                                                         *
rem *   2003-17-11 by OE1RIB@MIN.at                                           *
rem ***************************************************************************

CLS
Speed = 650000
SStep = 0

OPEN "com2:9600,N,8,1,RS,CD0,CS0,DS0" FOR RANDOM AS #1


CATSend "READ MODE", SStep, Speed, &H0, &H0, &H0, &H0, &H3
GOSUB Dump
FTMode$ = MID$(b$, LEN(b$), 1)
IF LEFT$(FTMode$, 1) = CHR$(&H88) OR LEFT$(FTMode$, 1) = CHR$(&H6) THEN
    FTMode$ = CHR$(&H8)
END IF
IF LEN(FTMode$) > 0 THEN
    PRINT "CURRENT MODE = " + HEX$(ASC(FTMode$))
END IF

CATSend "READ POWER", SStep, Speed, 0, 121, 0, 0, 187
GOSUB Dump
DataHigh = ASC(MID$(b$, 1, 1))
DataLow = ASC(MID$(b$, 2, 1))

PRINT
PRINT "-------------------"

CATSend "SET CW-MODE", SStep, Speed, 2, 0, 0, 0, 7
GOSUB Dump

CATSend "SET POWER", SStep, Speed, 0, 121, 11, DataLow, 188
GOSUB Dump

CATSend "SET LOCK", SStep, Speed, 0, 0, 0, 0, 0
GOSUB Dump

CATSend "PTT ON", SStep, Speed, 0, 0, 0, 0, 8
GOSUB Dump

PRINT
PRINT "-------------------"

CATSend "PTT OFF", SStep, Speed, 0, 0, 0, 0, &H88
GOSUB Dump

CATSend "UNLOCK", SStep, Speed, 0, 0, 0, 0, &H80
GOSUB Dump

CATSend "RESTORE POWER", SStep, Speed, 0, 121, DataHigh, DataLow, 188
GOSUB Dump

CATSend "RESTORE MODE", SStep, Speed, ASC(LEFT$(FTMode$, 1)), 0, 0, 0, 7
GOSUB Dump


PRINT
IF SStep = 1 THEN INPUT x

CLOSE #1
END

Dump:
n = LOC(1)
IF n > 0 THEN
    PRINT n; " ";
    b$ = INPUT$(n, #1)
    b$ = LEFT$(b$, n)
    PRINT DumpStr$(b$);
END IF
PRINT
RETURN


SUB CATSend (Text$, SStep, Speed, c1, c2, c3, c4, c5)
    DIM b$
    DIM n
    DIM i

    PRINT : PRINT Text$ + " ";
    IF SStep = 1 THEN
        INPUT x
    ELSE
        PRINT
    END IF
    b$ = CHR$(c1) + CHR$(c2) + CHR$(c3) + CHR$(c4) + CHR$(c5)
    PRINT DumpStr$(b$) + " --> ";
    PRINT #1, b$
    n = TIMER
    FOR i = 1 TO Speed
    NEXT i
    PRINT TIMER - n; " ";
END SUB

FUNCTION DumpStr$ (b$)
    DIM w$
    DIM h$
    DIM i

    w$ = ""
    FOR i = 1 TO LEN(b$)
        h$ = HEX$(ASC(MID$(b$, i, 1)))
        w$ = w$ + LEFT$("00", 2 - LEN(h$)) + h$ + " "
    NEXT i
    DumpStr$ = w$
END FUNCTION